Cream of the Crop 26/Cream of the Crop 26.iso/bbs/tmg108.zip/MAGIC.ZIP/FOREST.SCR

Text File | 1997-05-08 | 12KB | 424 lines

@#DEFINE
  CreatureFile FOREST.DAT
  Set ^VR20 0
  Location "fForest of Wolves"
@#INSTALL
`2Forest of Wolves
This is the Script version of the Forest of Wolves.  Compare it with the
version you can access from the Enter Realms menu.  (You shouldn't notice
a difference)
@#ITEMS
  NAME  1 "`2Potion of Healing"
  SCRID 1 "PotH-03091997-JO-N"
  STAT1 1 0 0 2500 1 10
  STAT2 1 1 1 0
@#ITEM1_FLAGS
  DATE 19970508 2
@#ITEM1_USE
  Writeln "`3  You take a drink of the Potion of Healing and a warm fire shoots through"
  Writeln "  your body.  It magically heals your wounds and completely refreshes you."
  Set ^CS10 ^CS11
@#ITEM1_USECOMBAT
  Gosub USE
@#ITEM1_IDENTIFY
WriteBlock
`%┌──────────────┐
`%│`3░░░░░░░░░░░░░░`%│`3 The Potion of Healing will restore your Hit Points
`%│`3░░░░░░░░░░░░░░`%│ `3to Maximum when the potion is used.
`%│`3░░░░░░░░░░░░░░`%│`9 (`%Heals all wounds`9)
`%│`3░░░░░░░░░░░░░░`%│
`%│`3░░░░░░░░░░░░░░`%│
`%│`3░░░░░░░░░░░░░░`%│
`%└──────────────┘DA
BC▄
C▄▄▄
C▐▄▄▄▌
C▐▄▄▄▌
B
EndBlock
@#ITEM1_LASTUSE
  Writeln "`9  (`%The vial is now empty`9)"
@#ITEM1_DROP
  Writeln "`9  The Potion vanishes when it touches the ground."
@#MONSTER
  STATS 1 38 28 21 200 400 68 3
  NAME  1 "Huge Grizzley Bear"
  WNAME 1 "Big Black Paw"
  ANAME 1 "Increadibly Thick Fur"
  DEATH 1 "RRRRRRRRRRRRRRRRRrrrrrrrrrrrrrrrr..."
  STATS 2 158 124 31 690 800 260 6
  NAME  2 "Huge Grizzley Bear"
  WNAME 2 "Big Black Paw"
  ANAME 2 "Increadibly Thick Fur"
  DEATH 2 "RRRRRRRRRRRRRRRRRrrrrrrrrrrrrrrrr..."
@#Event1
  Set ^VR03 400
  Mult ^VR03 ^CS22
  Random ^VR03 ^VR03
  Writeln "`9  You find a sack containing ^VR03 gold pieces in it."
  Add ^CS18 ^VR03
  Pause
  Writeln ""
  Return
@#Event2
  Writeln "`9  You are walking through the forest, whne you are hit by a bolt of"
  Writeln "  `1Blue`9 light.  It surrounds you, envelops you, and drains you of your"
  Writeln "  Energy, but you can feel it making you tougher."
  Random ^VR03 4
  Writeln "`%  You gain `4^VR03`% defense points."
  Add ^CS04 ^VR03
  Set ^VR03 ^CS10
  Random ^VR03 ^VR03
  Add ^VR03 -1
  If ^VR03 > 100
    Set ^VR03 100
  Endif
  If ^VR03 > 0
    Writeln "`%  You lose `4^VR03`% hit points."
    Add ^CS10 -^VR03
  Endif
  Pause
  Return
@#Event3
  Writeln "`9  You are walking through the forest, whne you are hit by a bolt of"
  Writeln "  `4Red`9 light.  It surrounds you, envelops you, and drains you of your"
  Writeln "  Energy, but you can feel it making you stronger."
  Random ^VR03 4
  Writeln "`%  You gain `4^VR03`% attack points."
  Add ^CS03 ^VR03
  Set ^VR03 ^CS10
  Random ^VR03 ^VR03
  Add ^VR03 -1
  If ^VR03 > 100
    Set ^VR03 100
  Endif
  If ^VR03 > 0
    Writeln "`%  You lose `4^VR03`% hit points."
    Add ^CS10 -^VR03
  Endif
  Pause
  Return
@#Event4
  Writeln "`9  You are walking through the forest, whne you are hit by a bolt of"
  Writeln "  `2Green`9 light.  It surrounds you, envelops you, and drains you of your"
  Writeln "  Energy, but you can feel it making you more agile."
  Random ^VR03 4
  Writeln "`%  You gain `4^VR03`% damage reduction points."
  Add ^CS05 ^VR03
  Set ^VR03 ^CS10
  Random ^VR03 ^VR03
  Add ^VR03 -1
  If ^VR03 > 100
    Set ^VR03 100
  Endif
  If ^VR03 > 0
    Writeln "`%  You lose `4^VR03`% hit points."
    Add ^CS10 -^VR03
  Endif
  Pause
  Return
@#Event5
  Writeln "`9  You find a gem partially hidden under a rock!"
  Add ^CS20 1
  Pause
  Return
@#Event6
  Writeln "`9  You stumble across a large cave in the middle of the wilderness."
  Writeln "`9  It is very dark, and smells pretty bad."
  Writeln ""
  DefaultCommand Y
  Write "`9  Do you Enter? (`3Y`9/`3N`9) [`%^VR21`9] : `%"
  ReadChar ^VR01
  If ^VR01 == Y
    Writeln "Yes."
    Writeln ""
    Writeln "`9  Entering the cave, you encounter a Huge Grizzley Bear!"
    If ^CS22 <= 4
      Combat ^GF29 Int 1
      Set ^VR05 5
      Set ^VR06 600
    Endif
    If ^CS22 > 4
      Combat ^GF29 Int 2
      Set ^VR05 8
      Set ^VR06 1200
    Endif
    If ^GF29 == 1
      Writeln "`c`%                         Searching the Cave :"
      Writeln "`#-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-"
      Writeln "`9  After defeating the Grizzley Bear, you search around its cave."
      Writeln "  You find the remains of many small animals, some remnants of fur,"
      Writeln "  But eventually you find some things of value."
      Writeln "`!  You find ^VR06 Gold and ^VR05 Gems!"
      Writeln ""
      Add ^CS18 ^VR06
      Add ^CS20 ^VR05
      Pause
    Endif
    Return
  Endif
  Writeln "No."
  Writeln ""
  Writeln "`9  You guess you'll never know what fortunes could lie in that cave."
  Return
@#Mail1
  SetStr ^VR04 "`%Bank Notice :"
  Random ^VR05 ^CS19
  Mail ^CS01 ^VR04
We regret to inform you that a mistake had been made in your favor.
The error has been corrected, and the sum of ^VR05 has
been removed from your balance.  We regret the error being made.
  MailCommands
Add ^CS19 -^VR05
  EndMail
  Return
@#Mail2
  SetStr ^VR04 "`%Bumbling Move!"
  Set ^VR05 2
  Set ^VR06 12
  Mult ^VR05 ^CS22
  Mult ^VR06 ^CS22
  If ^VR06 > ^CS10
    Set ^VR06 ^CS10
    Add ^VR06 -1
  Endif
  Mail ^CS01 ^VR04
On your way through town, you trip over your own feet and break your
arm.  You realize that even though the healers can fix it, you will
not be as strong as you once were.
(You lose ^VR05 attack points)
(You lose ^VR06 hit points due to pain)
  MailCommands
ADD ATT -^VR05
ADD CHP -^VR06
  EndMail
  Return
@#Mail3
  SetStr ^VR04 "`%Good Fortune!"
  Set ^VR05 ^CS22
  Add ^VR05 2
  Random ^VR05 ^VR05
  Mail ^CS01 ^VR04
On your way back to town, a large bird drops a sack at your feet and
flies off.  Being curious, you open the sack to reveal
^VR05 gems!  All beautifully polished.
  MailCommands
ADD ^CS20 ^VR05
  EndMail
  Return
@#Mail4
  If ^CS12 > 0
    Setstr ^VR04 "`%Strange Event!"
    Random ^VR05 ^CS22
    Mult ^VR05 2
    Mail ^CS01 ^VR04
On your way back to town, a shimmering green light shoots out of the sky
striking your ^CS13.  It now feels energized.
(Your weapon now has a +^VR05 bonus)
    MailCommands
Add ^CS03 ^VR05
Add ^CS12 ^VR05
    EndMail
  Endif
  Return
@#Mail5
  Set ^VR05 2000
  Mult ^VR05 ^CS22
  Mail ^CS01 `%Message from the Royal Family in Munich :
We have heard of your deeds, and wish you the best of luck in saving
Shamile.  Our treasurer has sent over a small gift of ^VR05 gold to aid you.
(Due to their influence, you gain 4 charm and lose 6 shame)
  MailCommands
Add ^CS06 4
Add ^CS07 -6
Add ^CS18 ^VR05
  EndMail
  Return
@#Event7
  Writeln "`9  You stumble across a small, quaint well nestled deep in the forest."
  Writeln "`9  It has a small wooden sign on it that says `3"Wishes : 1 gem"`9."
  Writeln ""
  DefaultCommand Y
  Write "`9  Do you throw one in? (`3Y`9/`3N`9) [`%^VR21`9] : `%"
  ReadChar ^VR01
  If ^VR01 == Y
    Writeln "Yes."
    If ^CS20 >= 1
      Add ^CS20 -1
      Writeln "`9  Nothing apparently happens."
      Random ^VR02 100
      Add ^VR02 ^CS08
      If ^VR02 <= 20
        Set ^VR03 1
      Endif
      If ^VR02 >= 21
        If ^VR02 <= 40
          Set ^VR03 2
        Endif
      Endif
      If ^VR02 >= 41
        If ^VR02 <= 60
          Set ^VR03 3
        Endif
      Endif
      If ^VR02 >= 61
        If ^VR02 <= 80
          Set ^VR03 4
        Endif
      Endif
      If ^VR02 >= 81
        If ^VR02 <= 100
          Set ^VR03 5
        Endif
      Endif
      Gosub Mail^VR03
      Return
    Endif
    Writeln ""
    Writeln "  `9You don't have a `4GEM`9 to throw in!"
    Return
  Endif
  Writeln "No."
  Writeln ""
  Writeln "`9  You realize you would just be throwing a gem away as wishes dont come true."
  Return
@#Event8
  Writeln "`9  You curse your bad luck as you trip over an upturned tree root, but when"
  Writeln "  you land face down in the mud, you are staring right at a 4-leaf clover."
  Writeln "`%  You gain `21`% luck"
  Add ^CS08 1
  Pause
  Return
@#Event9
  Writeln "`9  From out of nowhere, a large black cat streaks across your path."
  Writeln "`%  You lose `21`% luck"
  Add ^CS08 -1
  Pause
  Return
@#Event10
  SharedEvent 1
  Pause
  Return
@#Event11
  WriteBlock
`9  You remember hearing the rumor about a new church being formed out in
`9  the forest as you stumble upon a small wooden structure.  It looks like
`9  new construction, but as you get near, you realize it is nothing more
`9  than a blind for hunting deer and other animals.
`9  You think to yourself that the rumors are untrue.
  EndBlock
  Return
@#Event12
  SharedEvent 3
  Return
@#Event13
  Writeln "`9  You encounter an ugly hag, and when she sees that you are not repulsed by"
  Writeln "`9  her appearance, she reaches into her bag and hands you a vial of liquid."
  Item 1
  Return
@#SpecialEvent
  Writeln "`c`%                             Special Event:"
  Writeln "`#-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-"
  Random ^VR02 13
  Gosub Event^VR02
  ReDispMenu FALSE
  Return
@#Fight
  If ^CS26 >= 1
    MonsterAvailable ^GF28
    If ^GF28 == 1
      Random ^VR02 100
      Add ^VR02 -^CS08
      If ^VR02 < 20
        Gosub SpecialEvent
        ReDispMenu FALSE
        Return
      Endif
      Combat ^GF29 Ext
      Add ^CS26 -1
      Return
    Endif
    Writeln ""
    Writeln "`9  Sorry, there is `4NOTHING`9 here for you to fight."
    ReDispMenu FALSE
    Return
  Endif
  Writeln ""
  Writeln "`9  Sorry, the forest is `4EMPTY`9.  Perhaps you should return tomorrow."
  ReDispMenu FALSE
  Return
@#Deposit
  Writeln ""
  Writeln "  `3You wander over to a nearby tree, and while nobody is looking, pull a"
  Writeln "  'special' branch and a panel opens up.  You put your money belt in, close"
  Writeln "  the panel and hear the whirring noise.  After a few seconds, you open the"
  Writeln "  panel and retrieve your money belt and receipt."
  Add ^CS19 ^CS18
  Set ^CS18 0
  ReDispMenu FALSE
  Return
@#FOREST_MENU
SHL
`c                           `%Forest of Wolves:
`#-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
`9  You tread lightly and quickly through the woods, almost stalking your
`9  prey.  You see small rabbits and squirrels, but they refuse to go toe-to
`9  toe with you, so you know you need to look for larger prey.  What do you
`9  wish to do?
`9
`3  (`#^MC01`3)earch for larger prey.
`3  (`#^MC02`3)ealers temple.
`3  (`#^MC03`3)eave this scary place.
@#MAIN
  Menu Forest_menu
  Writeln ""
  Write "`9   HP`%: `9(`%^CS10 `9/`% ^CS11`9)   Fights Left `%: ^CS26"
  Writeln "    `9Gold `%: &CS18     `9Gems `%: &CS20"
  Writeln ""
  Writeln "   `2Forest of Wolves : "
  DefaultCommand L
  If ^CS26 >= 1
    DefaultCommand S
  Endif
  If ^GF29 == 2
    DefaultCommand L
  Endif
  ReadMenuCommands ^VR02
  Writeln "^VR02"
  If ^VR02 == L
    Halt
  Endif
  If ^VR02 == S
    Gosub Fight
  Endif
  If ^VR02 == H
    Healer
    ReDispMenu TRUE
  Endif
  If ^VR02 == F
    FindPlayers
  Endif
  If ^VR02 == R
    DisplayRanks
  Endif
  If ^VR02 == V
    DisplayStats
  Endif
  If ^VR02 == =
    DisplayCreatures
  Endif
  If ^VR02 == D
    Gosub Deposit
  Endif
  If ^VR02 == ?
    DisplayMenu
  Endif
  If ^VR02 == Y
    Inventory
  Endif
  If ^VR02 == M
    Item 1
  Endif

@#